• Witaj na Forum Arduino Polska! Zapraszamy do rejestracji!
  • Znajdziesz tutaj wiele informacji na temat hardware / software.
Witaj! Logowanie Rejestracja


Ocena wątku:
  • 0 głosów - średnia: 0
  • 1
  • 2
  • 3
  • 4
  • 5
Button Box
#1
Witam wszystkich,
z góry przepraszam za wszystkie błędy ale jestem tutaj nowy i nie bardzo znam jeszcze arduino,
mam pytanie chciałbym sobie zrobić button box do komputera coś podobnego do tego https://www.youtube.com/watch?v=Z7Sc4MJ8RPM
ale z dwoma przełącznikami obrotowymi 8 pozycyjnymi konkretnie takimi: https://botland.com.pl/przelaczniki-obro...-30mm.html
Przerobiłem schemat ten który jest na filmie na taki: 
   
Oraz kod na:
Kod:
//BUTTON BOX
//USE w ProMicro
//Tested in WIN10 + Assetto Corsa
//AMSTUDIO
//20.8.17

#include <Keypad.h>
#include <Joystick.h>

#define ENABLE_PULLUPS
#define NUMROTARIES 4
#define NUMBUTTONS 24
#define NUMROWS 2
#define NUMCOLS 8


byte buttons[NUMROWS][NUMCOLS] = {
 {0,1,2,3,4,5,6,7},
 {8,9,10,11,12,13,14,15},
};

struct rotariesdef {
 byte pin1;
 byte pin2;
 int ccwchar;
 int cwchar;
 volatile unsigned char state;
};

rotariesdef rotaries[NUMROTARIES] {
 {0,1,24,25,0},
 {2,3,26,27,0},
 {4,5,28,29,0},
 {6,7,30,31,0},
};

#define DIR_CCW 0x10
#define DIR_CW 0x20
#define R_START 0x0

#ifdef HALF_STEP
#define R_CCW_BEGIN 0x1
#define R_CW_BEGIN 0x2
#define R_START_M 0x3
#define R_CW_BEGIN_M 0x4
#define R_CCW_BEGIN_M 0x5
const unsigned char ttable[6][4] = {
 // R_START (00)
 {R_START_M,            R_CW_BEGIN,     R_CCW_BEGIN,  R_START},
 // R_CCW_BEGIN
 {R_START_M | DIR_CCW, R_START,        R_CCW_BEGIN,  R_START},
 // R_CW_BEGIN
 {R_START_M | DIR_CW,  R_CW_BEGIN,     R_START,      R_START},
 // R_START_M (11)
 {R_START_M,            R_CCW_BEGIN_M,  R_CW_BEGIN_M, R_START},
 // R_CW_BEGIN_M
 {R_START_M,            R_START_M,      R_CW_BEGIN_M, R_START | DIR_CW},
 // R_CCW_BEGIN_M
 {R_START_M,            R_CCW_BEGIN_M,  R_START_M,    R_START | DIR_CCW},
};
#else
#define R_CW_FINAL 0x1
#define R_CW_BEGIN 0x2
#define R_CW_NEXT 0x3
#define R_CCW_BEGIN 0x4
#define R_CCW_FINAL 0x5
#define R_CCW_NEXT 0x6

const unsigned char ttable[7][4] = {
 // R_START
 {R_START,    R_CW_BEGIN,  R_CCW_BEGIN, R_START},
 // R_CW_FINAL
 {R_CW_NEXT,  R_START,     R_CW_FINAL,  R_START | DIR_CW},
 // R_CW_BEGIN
 {R_CW_NEXT,  R_CW_BEGIN,  R_START,     R_START},
 // R_CW_NEXT
 {R_CW_NEXT,  R_CW_BEGIN,  R_CW_FINAL,  R_START},
 // R_CCW_BEGIN
 {R_CCW_NEXT, R_START,     R_CCW_BEGIN, R_START},
 // R_CCW_FINAL
 {R_CCW_NEXT, R_CCW_FINAL, R_START,     R_START | DIR_CCW},
 // R_CCW_NEXT
 {R_CCW_NEXT, R_CCW_FINAL, R_CCW_BEGIN, R_START},
};
#endif

byte rowPins[NUMROWS] = {21,20};
byte colPins[NUMCOLS] = {19,18,15,14,16,10,9,8};

Keypad buttbx = Keypad( makeKeymap(buttons), rowPins, colPins, NUMROWS, NUMCOLS);

Joystick_ Joystick(JOYSTICK_DEFAULT_REPORT_ID,
 JOYSTICK_TYPE_JOYSTICK, 32, 0,
 false, false, false, false, false, false,
 false, false, false, false, false);

void setup() {
 Joystick.begin();
 rotary_init();}

void loop() {

 CheckAllEncoders();

 CheckAllButtons();

}

void CheckAllButtons(void) {
     if (buttbx.getKeys())
   {
      for (int i=0; i<LIST_MAX; i++)  
       {
          if ( buttbx.key[i].stateChanged )  
           {
           switch (buttbx.key[i].kstate) {  
                   case PRESSED:
                   case HOLD:
                             Joystick.setButton(buttbx.key[i].kchar, 1);
                             break;
                   case RELEASED:
                   case IDLE:
                             Joystick.setButton(buttbx.key[i].kchar, 0);
                             break;
           }
          }  
        }
    }
}


void rotary_init() {
 for (int i=0;i<NUMROTARIES;i++) {
   pinMode(rotaries[i].pin1, INPUT);
   pinMode(rotaries[i].pin2, INPUT);
   #ifdef ENABLE_PULLUPS
     digitalWrite(rotaries[i].pin1, HIGH);
     digitalWrite(rotaries[i].pin2, HIGH);
   #endif
 }
}


unsigned char rotary_process(int _i) {
  unsigned char pinstate = (digitalRead(rotaries[_i].pin2) << 1) | digitalRead(rotaries[_i].pin1);
 rotaries[_i].state = ttable[rotaries[_i].state & 0xf][pinstate];
 return (rotaries[_i].state & 0x30);
}

void CheckAllEncoders(void) {
 for (int i=0;i<NUMROTARIES;i++) {
   unsigned char result = rotary_process(i);
   if (result == DIR_CCW) {
     Joystick.setButton(rotaries[i].ccwchar, 1); delay(50); Joystick.setButton(rotaries[i].ccwchar, 0);
   };
   if (result == DIR_CW) {
     Joystick.setButton(rotaries[i].cwchar, 1); delay(50); Joystick.setButton(rotaries[i].cwchar, 0);
   };
 }
}
I tu mam pytanie czy to będzie działać, czy można w ten sposób w bibliotece Keypad zaadresować przyciski bo nigdzie nie widziałem żeby, była taka duża różnica między wierszami a kolumnami, przeważnie jest to 4x3 4x4?
Z góry dziękuję za odpowiedź i przepraszam jeżeli pytanie jest banalne, ale nie mam arduino pro micro i przełącznika, żeby to sprawdzić.
 
Odpowiedź
#2
W tej bibliotece możesz zrobić dowolna wielkość klawiatury  jeśli tylko ci pinów na tyle wystarcz.
[Obrazek: banerelektronika.jpg]



Jeśli pomogłem podziękuj punktem reputacji Wink
 
Odpowiedź
#3
Dzięki za odpowiedź, zamawiam części i próbuje złożyć wszystko w jedną całość.
 
Odpowiedź
#4
Tak dowolna to przesadziłem ale spora bo ogranicza cie zmienia int .
[Obrazek: banerelektronika.jpg]



Jeśli pomogłem podziękuj punktem reputacji Wink
 
Odpowiedź
#5
a teraz moje pytanie Tongue jak do tej biblioteki dopisać kod zeby np. po kliknięciu danego przycisku zapalała się dioda/migała tak jak w grze np. od kierunkowskazu lub zaciągnięty hamulec ręczny?
 
Odpowiedź
#6
Jeżeli planujesz to do ETS2 to ściągnij sobie plugin który obsługuje ledy Wink
 
Odpowiedź
#7
(25-11-2017, 17:40)soczek4024 napisał(a): Jeżeli planujesz to do ETS2 to ściągnij sobie plugin który obsługuje ledy Wink

No właśnie tyko gdzie tego szukać, jakieś instrukcje czy cuś :Big Grinutton box już mam Big Grin
 
Odpowiedź
#8
Ja znalazłem na internecie dużo rzeczy do ets2 musisz poszukać, tylko niestety kontrolki są napisane na " kierunki, rezerwa, hamulec ręczny i chyba światła zwykle i drogowe. Polecam Ci też SimHub Wink
 
Odpowiedź
#9
Simhub mam ale i tak troche tego nie ogarniam Tongue
 
Odpowiedź
#10
Kod:
#include <LiquidCrystal.h>
#include <Servo.h>

const int SPEEDO_PIN      = A1;
const int RPM_PIN         = A0;
const int LEFT_INDICATOR  = A2;   /// Podłączasz GND dioda i A2 najlepiej użyc arduino nano
const int RIGHT_INDICATOR = A3;
const int PARKING_BREAK   = A4;
const int FUEL_WARNING    = A5;

// Servo variables
Servo speedo;
Servo rpm;



#define PACKET_SYNC 0xFF
#define PACKET_VER  2

#define SERVO_DIR_NORMAL false
#define SERVO_DIR_INVERT true

int serial_byte;

LiquidCrystal lcd(12, 11, 10, 9, 8, 7, 6, 5, 4, 3, 2);

void setup()
{
Serial.begin(115200);

lcd.begin(16, 2);
lcd.print("Self Test");

// Initialise servos
speedo.attach(SPEEDO_PIN);
speedo.write(180);

rpm.attach(RPM_PIN);
rpm.write(180);

// Initialise LEDs
pinMode(LEFT_INDICATOR, OUTPUT);
pinMode(RIGHT_INDICATOR, OUTPUT);
pinMode(PARKING_BREAK, OUTPUT);
pinMode(FUEL_WARNING, OUTPUT);

digitalWrite(LEFT_INDICATOR, 0);
digitalWrite(RIGHT_INDICATOR, 0);
digitalWrite(PARKING_BREAK, 0);
digitalWrite(FUEL_WARNING, 0);


delay(500);

speedo.write(0);
rpm.write(0);
digitalWrite(LEFT_INDICATOR, 1);
digitalWrite(RIGHT_INDICATOR, 1);
digitalWrite(PARKING_BREAK, 1);
digitalWrite(FUEL_WARNING, 1);


delay(500);

speedo.write(180);
rpm.write(180);
digitalWrite(LEFT_INDICATOR, 0);
digitalWrite(RIGHT_INDICATOR, 0);
digitalWrite(PARKING_BREAK, 0);
digitalWrite(FUEL_WARNING, 0);


lcd.clear();
lcd.print("Wait");

// Wait a second to ensure serial data isn't from re-programming
delay(1000);
lcd.clear();
lcd.print("Ready");
}



void read_serial_byte_set_servo(Servo& servo, bool invert)
{
serial_byte = Serial.read();
serial_byte = (serial_byte < 0) ? 0 : ((serial_byte > 180) ? 180 : serial_byte);
if (invert)
  servo.write(180 - serial_byte);
else
  servo.write(serial_byte);
}

void skip_serial_byte()
{
(void)Serial.read();
}

void digitalWriteFromBit(int port, int value, int shift)
{
digitalWrite(port, (value >> shift) & 0x01);
}

void loop()
{
if (Serial.available() < 16)
  return;

serial_byte = Serial.read();
if (serial_byte != PACKET_SYNC)
  return;
 
serial_byte = Serial.read();
if (serial_byte != PACKET_VER)
{
  lcd.clear();
  lcd.print("PROTOCOL VERSION ERROR");
  return;
}

read_serial_byte_set_servo(speedo, SERVO_DIR_INVERT); // Speed  
read_serial_byte_set_servo(rpm, SERVO_DIR_INVERT); // RPM

skip_serial_byte(); // Brake air pressure
skip_serial_byte(); // Brake temperature
skip_serial_byte(); // Fuel ratio
skip_serial_byte(); // Oil pressure
skip_serial_byte(); // Oil temperature
skip_serial_byte(); // Water temperature
skip_serial_byte(); // Battery voltage
 

// Truck lights byte
serial_byte = Serial.read();
digitalWriteFromBit(LEFT_INDICATOR,  serial_byte, 5);  
digitalWriteFromBit(RIGHT_INDICATOR, serial_byte, 4);

// Warning lights bytes

serial_byte = Serial.read();  
digitalWriteFromBit(PARKING_BREAK, serial_byte, 7);
digitalWriteFromBit(FUEL_WARNING, serial_byte, 3);  

// Enabled flags
serial_byte = Serial.read();

// Text length
int text_len = Serial.read();

// Followed by text
if (0 < text_len && text_len < 127)
{
  lcd.clear();
  for (int i = 0; i < text_len; ++i)
  {
    while (Serial.available() == 0) // Wait for data if slow
    {
      delay(2);
    }
    serial_byte = Serial.read();
    if (serial_byte < 0 && serial_byte > 127)
      return;
   
    if (serial_byte == '\n')
      lcd.setCursor(0, 1);
    else
      lcd.print(char(serial_byte));
//      delay(2);
  }
}

}


Załączone pliki
.zip   ets2_dashboard_v3.zip (Rozmiar: 34.91 KB / Pobrań: 3)
 
Odpowiedź
  


Skocz do:


Przeglądający: 1 gości